# TModi.ctl: Displays the Current Oracle Data Integrator Module Setup
# $Id: TModi.ctl,v 1.2 2013/10/30 07:18:34 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/TModi.ctl,v 1.2 2013/10/30 07:18:34 RDA Exp $
#
# Change History
# 20130211  KRA  Initial RDA 8 version.

=head1 NAME

OFM:TModi - Displays the Current Oracle Data Integrator Module Setup

=head1 DESCRIPTION

This test module displays the current Oracle Data Integrator module setup,
indicating which master and work repositories, which technical environments,
and which journals are collected.

=cut

section tool
call unshift(@{CUR.W_NEXT},'test')

section test

macro display_setup
{var ($id1,$id2,@tbl) = @arg
 var $fmt = ' %-*s %-7s%-7s'
 var $lgt = 4
 var %ttl = ('env','Tech.',\
             'mst','Master',\
             'log','Journal',\
             'wrk','Work')
 var %var = ('env','GRP.ODI.B_TECH_EXPORT_',\
             'mst','GRP.ODI.B_MASTER_EXPORT_',\
             'log','GRP.ODI.B_LOG_EXPORT_',\
             'wrk','GRP.ODI.B_WORK_EXPORT_')

 # Determine the biggest name length
 loop $id (@tbl)
 {var $log = ${T_LOGIN_${VAR.id}}
  var $lgt = max($lgt,length($log))
  var $log{$id} = $log
 }
 var $lgt = min($lgt,50)

 # Display the set
 dump $ttl{$id1},' Repository Export Setup:'
 dump tput('bold'),sprintf($fmt,$lgt,'Name',\
                                $ttl{$id1},\
                                $ttl{$id2}),tput('off')
 loop $id (@tbl)
 {var $key1 = concat($var{$id1},$id)
  var $key2 = concat($var{$id2},$id)
  dump sprintf($fmt,$lgt,$log{$id},cond(${VAR.key1},'Yes','No'),\
                                   cond(${VAR.key2},'Yes','No'))
 }
 dump
}

if @{W_MASTER_SET}
 call display_setup('mst','env',last)

if @{W_WORK_SET}
 call display_setup('wrk','log',last)

dump 'Other Settings:'
var %ttl = ('T_BEGIN','From date',\
            'T_END',  'To date')
loop $key ('D_HOME','T_BEGIN','T_END')
{if ${GRP.ODI.${VAR.key}}
  dump sprintf(' %-10s %s',concat(nvl($ttl{$key},$key),':'),last)
}

=head1 SEE ALSO

L<OFM:DCodi|collect::OFM:DCodi>

=begin credits

=over 10

=item RDA 4.10:  Sarath Babu, Benoit Gagnon, FX Nicolas.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut