# DCotd.ctl:322:Collects Oracle Traffic Director Information
# $Id: DCotd.ctl,v 1.1 2014/02/04 15:52:27 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCotd.ctl,v 1.1 2014/02/04 15:52:27 RDA Exp $
#
# Change History
# 20140204  KRA  Initial version.

=head1 NAME

OFM:DCotd - Collects Oracle Traffic Director Information

=head1 DESCRIPTION

This module collects information related to Oracle Traffic Director.

The following reports can be generated and are regrouped under C<Oracle
Traffic Director>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.OTD module ...',tput('off')

# Initialization
var $INS_ROOT = ${D_INSTANCE_ROOT:''}
var $OTD_HOME = ${D_HOME:''}
var $TAIL     = ${DFT.N_TAIL:1000}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle Traffic Director'

# Load the common macros
run RDA:library()

=head1 TRAFFIC DIRECTOR INFORMATION

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Oracle Traffic Director
collection.

=cut

debug ' Inside OTD module, collecting defined abbreviations'
report abbr
prefix
{write '---+ Oracle Traffic Director Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 version_info - Version Information

Gathers Oracle Traffic Director version information.

=cut

debug ' Inside OTD module, gathering version information'
pretoc '2:Server Information'
if ?testFile('f',catFile($OTD_HOME,'bin',${AS.EXE:'tadm'}))
{var $cmd = concat(lastTestCommand(),' --version')
 report version_info
 prefix
 {write '---+ Oracle Traffic Director Version Information'
  write '---## Using: ',encode($cmd)
 }
 call writeCommand(concat($cmd,' 2>&1'))
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Version Information]]'
}

=head2 Configuration Files

Gathers Administration Server-related configuration files.

=cut

if ?testDir('d',catDir($OTD_HOME,'admin-server'))
{debug ' Inside OTD module, collecting the admin configuration files'
 pretoc '3:Configuration Files'
 call sort_files(4,0,grepDir(catDir($top = lastDir(),'config'),'^\.+$','pv'))
 unpretoc

=head2 Log Files

Gathers Administration Server-related log files.

=cut

 debug ' Inside OTD module, collecting the admin log files'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,grepDir(catDir($top,'logs'),'^\.+$','pv'))
 unpretoc
}
unpretoc

=head1 TRAFFIC DIRECTOR INSTANCE INFORMATION

=head2 Configuration Files

Gathers Traffic Director instance-related configuration files.

=cut

loop $ins (@{T_INSTANCES})
{debug ' Inside OTD module, analyzing instance ',$ins
 var $top = catDir($INS_ROOT,$ins)
 pretoc "2:'",$ins,"' Instance"

 debug '  - collecting the configuration files'
 pretoc '3:Configuration Files'
 call sort_files(4,0,grepDir(catDir($top,'config'),'^\.+$','pv'))
 unpretoc

=head2 Log Files

Gathers Traffic Director instance-related log files.

=cut

 debug '  - collecting the log files'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,grepDir(catDir($top,'logs'),'^\.+$','pv'))
 unpretoc 2
}

unpretoc

=head1 SEE ALSO

L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 8.03: Walter Lee.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut