# DCjboss.ctl:303:Collects JBoss Application Server Information
# $Id: DCjboss.ctl,v 1.1 2015/03/18 22:18:34 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCjboss.ctl,v 1.1 2015/03/18 22:18:34 RDA Exp $
#
# Change History
# 20150309  KRA  Initial version.

=head1 NAME

OFM:DCjboss - Collects JBoss Application Server Information

=head1 DESCRIPTION

This module collects JBoss Application Server-related information. The module
covers JBoss Application Server 6 and later.

The following reports can be generated and are regrouped under C<JBoss
Application Server>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.JBOSS module ...',tput('off')

# Initialization
var $HOME = ${D_HOME/P:''}
var $MODE = ${W_MODE:'STANDALONE'}
var $TAIL = ${DFT.N_TAIL:1000}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:JBoss Application Server'

# Set the symbols
call setSymbol('$JBOSS_HOME',$HOME)

# Load the common macros
run RDA:library()

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the JBoss Application Server home
collection.

=cut

debug ' Inside JBOSS module, collecting defined abbreviations'
report abbr
prefix
{write '---+ JBoss Application Server Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head1 JBOSS SERVER INFORMATION

=head2 Start Scripts

Gathers the JBoss Application Server-related start scripts.

=cut

debug ' Inside JBOSS module, collecting the start scripts'
pretoc '2:Start Scripts'
call sort_files(3,0,grepDir(catDir($HOME,'bin'),'\.RSA$','pv'))
unpretoc

=head1 DOMAIN INFORMATION

=head2 Configuration Files

Gathers domain-related configuration files.

=cut

if compare('eq',$MODE,'DOMAIN')
{debug ' Inside JBOSS module, collecting the domain configuration files'
 pretoc '2:Domain Information'
 pretoc '3:Configuration Files'
 call sort_files(4,0,\
   grepDir(catDir($HOME,'domain','configuration'),'^\.+$','pv'))
 unpretoc

=head2 Log Files

Gathers domain-related log files.

=cut

 debug ' Inside JBOSS module, collecting the domain log files'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,\
   grepDir(catDir($HOME,'domain','log'),'^\.+$','pv'))
 unpretoc

=head1 MANAGED SERVER INFORMATION

=head2 Server Configuration Files

Gathers domain server-related configuration files.

=cut

 debug ' Inside JBOSS module, collecting the domain server configuration files'
 pretoc '3:Server Configuration Files'
 call sort_files(4,0,\
   grepDir(catDir($HOME,'appclient','configuration'),'^\.+$','pv'))
 unpretoc

=head2 Server Log Files

Gathers domain server-related log files.

=cut

 loop $nam (findDir($dir = catDir($HOME,'domain','servers'),'^\.+$','nv'))
 {debug ' Inside JBOSS module, analyzing domain server ',$nam
  debug '   - Collecting the domain server log files'
  pretoc "3:'",$nam,"' Server Log Files"
  call sort_files(4,$TAIL,grepDir(catDir($dir,$nam,'log'),'^\.+$','pv'))
  unpretoc
 }
 unpretoc 2
}

=head1 STANDALONE SERVER INFORMATION

=head2 Server Configuration Files

Gathers standalone server-related configuration files.

=cut

if compare('eq',$MODE,'STANDALONE')
{debug ' Inside JBOSS module, collecting the standalone server config files'
 pretoc '2:Standalone Server Information'
 pretoc '3:Server Configuration Files'
 call sort_files(4,0,\
   grepDir(catDir($HOME,'standalone','configuration'),'^\.+$','pv'))
 unpretoc

=head2 Server Log Files

Gathers standalone server-related log files.

=cut

 debug ' Inside JBOSS module, collecting the standalone server log files'
 pretoc '3:Server Log Files'
 call sort_files(4,$TAIL,grepDir(catDir($HOME,'standalone','log'),'^\.+$','pv'))
 unpretoc 2
}

unpretoc

=head1 SEE ALSO

L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 8.08: Ian Reid.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut