# DCbi.ctl:397:Collects Oracle Business Intelligence Enterprise Edition Info.
# $Id: DCbi.ctl,v 1.5 2015/07/03 11:49:17 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/BI/DCbi.ctl,v 1.5 2015/07/03 11:49:17 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

BI:DCbi - Collects Oracle Business Intelligence Enterprise Edition Information

=head1 DESCRIPTION

This module collects information related to Oracle Business Intelligence
Enterprise Edition, formerly known as Siebel Business Analytics.

The following reports can be generated and are regrouped under C<Oracle
Business Intelligence Enterprise Edition>:

=cut

echo tput('bold'),'Processing BI.BI module ...',tput('off')

# Initialization
var $ORACLE_HOME = ${D_ORACLE_HOME/P:''}

=head1 BUSINESS INTELLIGENCE ENTERPRISE EDITION INFORMATION

Includes the reports generated by the L<abr:IREQ|collect::OFM:DCireq> module
about the Oracle instances and their associated Oracle homes.

=cut

if or(${B_REQ_IREQ},\
      testDir('d',catDir($ORACLE_HOME,'bifoundation')),\
      testDir('d',catDir($ORACLE_HOME,'rcu')))
{# Analyze the instance requests
 var %tbl = ()
 loop $req (${CUR.O_SETUP}->search('^IREQ_BI_BI_OI'))
 {var $ins = $req->get_first('I_ORACLE_INSTANCE')
  if ?$ins->get_first('I_ORACLE_HOME')->get_prime('I_COMMON_HOME')
   var $tbl{last->get_oid,$req->get_oid} = $ins->get_first('D_ORACLE_INSTANCE')
  else
   var $tbl{'CH',$req->get_oid} = $ins->get_first('D_ORACLE_INSTANCE')
 }

 # Collect the BI 11g information
 toc '%PUSH("0:   * Oracle Business Intelligence Enterprise Edition")%'
 loop $oid (keys(%tbl))
 {toc '%PUSH("1+:Common Product Home")%'
  toc '%INCLUDE("OFM_IREQ_BI_BI_',$oid,'_TF.toc")%'
  toc '%POP%'
  loop $tid (keys($tbl = $tbl{$oid}))
  {toc '%PUSH("0:      * ',"'",basename($tbl->{$tid}),"'",' Instance")%'
   toc '%PUSH("%SPLIT%")%'
   toc '%PUSH("1++:Associated Oracle Home")%'
   toc '%INCLUDE("OFM_',replace($tid,'_OI','_OH'),'_TF.toc",1)%'
   toc '%POP2%'
   toc '%PUSH("%SPLIT%")%'
   toc '%PUSH("1++:Instance Home")%'
   toc '%INCLUDE("OFM_',$tid,'_TF.toc")%'
   toc '%POP3%'
  }
 }
 toc '%POP%'

=head2 HCVE

When requested, performs the preinstallation checks.

=cut

 if ${B_HCVE_CHECKS}
 {debug ' Inside BI module, executing the preinstallation checks'
  test TOOL:TLhcve('BI:Abi1111_gen')
 }
}
else
{# Initialization
 var $BI_AGE  = ${R_LOG_AGE/T:5}
 var $BI_DATA = ${D_DATA:''}
 var $BI_HOME = ${D_HOME:''}
 var $BI_TAIL = ${N_TAIL:5000}

 var $TOC = '%TOC%'
 var $TOP = '[[#Top][Back to top]]'
 pretoc '1:Oracle Business Intelligence Enterprise Edition'

 # Load the common macros
 run RDA:library()

=head2 bi_version - Version Information

Gathers version information.

=cut

 debug ' Inside BI module, getting version information'
 report bi_version
 call cat_file(catDir($BI_HOME,'server','Document'),'version.txt')
 if isCreated(true)
  toc '2:[[',getFile(),'][rda_report][Version Information]]'

=head2 present_config - Presentation Server

Gathers presentation server configuration information.

=cut

 pretoc '2:Configuration Files'

 debug ' Inside BI module, getting presentation server configuration'
 report present_config
 call cat_file(catDir($BI_DATA,'web','config'),'instanceconfig.xml')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Presentation Server]]'

=head2 sched_config - Scheduler

Gathers scheduler configuration information.

=cut

 debug ' Inside BI module, getting scheduler configuration'
 report sched_config
 call cat_file(catDir($BI_DATA,'scheduler','config'),'instanceconfig.xml')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Scheduler]]'

=head2 server_config - Server

Gathers server configuration information.

=cut

 debug ' Inside BI module, getting server configuration'
 report server_config
 call cat_file(catDir($BI_HOME,'server','Config'),'NQSConfig.INI')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Server]]'

=head2 cluster_config - Cluster Controller

Gathers cluster controller configuration information.

=cut

 debug ' Inside BI module, getting cluster controller configuration'
 report cluster_config
 call cat_file(catDir($BI_HOME,'server','Config'),'NQClusterConfig.INI')
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Cluster Controller]]'
 unpretoc

=head2 Log Files

Gathers important log files.

=cut

 pretoc '2:Log Files'

 debug ' Inside BI module, getting server log'
 report server_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQServer.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Server]]'

 debug ' Inside BI module, getting query log'
 report query_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQQuery.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Query]]'

 debug ' Inside BI module, getting scheduler log'
 report scheduler_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQScheduler.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Scheduler]]'

 debug ' Inside BI module, getting administration tool log'
 report admin_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQSAdminTool.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Administration Tool]]'

 debug ' Inside BI module, getting install log'
 report install_log
 call tail_file(catDir($BI_HOME,'log'),'install.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Install]]'

 debug ' Inside BI module, getting cluster controller log'
 report cluster_log
 call tail_file(catDir($BI_HOME,'server','Log'),'NQCluster.log',$BI_TAIL)
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Cluster Controller]]'

 pretoc '3:Presentation Server'
 var $dir = catDir($BI_DATA,'web','log')
 report concat
 loop $fil (grepDir($dir,'^sawlog.*\.log$',concat('im',$BI_AGE)),\
            'sawserver.out.log')
 {report concat('web_',$fil)
  call tail_file($dir,$fil,$BI_TAIL)
  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',encode($fil),']]'
 }
 unpretoc

 pretoc '3:Javahost'
 var $dir = catDir($BI_DATA,'web','log','javahost')
 loop $fil (grepDir($dir,'^jhost0\.log\.',concat('im',$BI_AGE)))
 {report concat('java_',$fil)
  call tail_file($dir,$fil,$BI_TAIL)
  if isCreated(true)
   toc '4:[[',getFile(),'][rda_report][',encode($fil),']]'
 }
 unpretoc 2

=head2 repository - Repositories

Gathers repositories.

=cut

 var @fil = ()
 loop $rep (@{T_REPOSITORY})
  call push(@fil,catFile($BI_HOME,'server','Repository',$rep))
 if @fil
  run BI:BIinfo(2,@fil)
 unpretoc
}

=head1 SEE ALSO

L<BI:BIinfo|collect::BI:BIinfo>,
L<BI:BIr11|collect::BI:BIr11>,
L<OFM:DCireq|collect::OFM:DCireq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.11: Ravindrasinh Parmar.

=item RDA 4.15: John Whitaker.

=item RDA 4.16: Greg Cook, Andrew Salt.

=item RDA 4.20: Mitra Veluri.

=item RDA 4.24: Greg Cook, Andrew Salt.

=item RDA 8.03: Ian Bristow.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut