# DCwcs.ctl:329:Collects Oracle WebCenter Sites Information
# $Id: DCwcs.ctl,v 1.3 2015/09/22 15:09:34 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCwcs.ctl,v 1.3 2015/09/22 15:09:34 RDA Exp $
#
# Change History
# 20150914  KRA  Improve 'Manifest Information' section.

=head1 NAME

OFM:DCwcs - Collects Oracle WebCenter Sites Information

=head1 DESCRIPTION

This module collects Oracle WebCenter Sites-related information. The following
reports can be generated and are regrouped under C<Oracle WebCenter Sites>:

=cut

use Xml

echo tput('bold'),'Processing OFM.WCS module ...',tput('off')

# Initialization
var $DOMAIN = ${D_DOMAIN_HOME:''}
var $HOME   = ${D_HOME:''}
var $TAIL   = ${DFT.N_TAIL:1000}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle WebCenter Sites'

# Set the symbols
call setSymbol('$WCS_HOME',$HOME)

# Load the common macros
run OFM:WLSlib()
run RDA:library()

=head1 ORACLE WEBCENTER SITES HOME COLLECTIONS

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Oracle WebCenter Sites home
collection.

=cut

debug ' Inside WCS module, collecting defined abbreviations'
report abbr
prefix
{write '---+ Oracle WebCenter Sites Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 Manifest Information

Gathers the Oracle WebCenter Sites home manifest information.

=cut

debug ' Inside WCS module, getting WebCenter Sites home manifest information \
        (can take time)'
pretoc '2:Manifest Information'
call dsp_manifest(3,[grepDir($HOME,'\.jar$','inp')])
unpretoc

=head2 Configuration Files

Collects Oracle WebCenter Sites-related configuration files.

=cut

debug ' Inside WCS module, collecting the configuration files'
pretoc '2:Configuration Files'
call sort_files(3,0,\
  grepDir($HOME,'\.ini$','inp'),\
  grepDir(catDir($HOME,'bin'),'\.(properties|xml)$','inp'),\
  grepDir(catDir($HOME,'ominstallinfo'),'\.ini$','inp'))
unpretoc

=head2 Log Files

Collects Oracle WebCenter Sites-related log files.

=cut

debug ' Inside WCS module, collecting the log files'
pretoc '2:Log Files'
call sort_files(3,$TAIL,\
  grepDir(catDir($HOME,'logs'),'\.log','ipt'),\
  grepDir(catDir($HOME,'ominstallinfo'),'\.log','ipt'))
unpretoc

=head1 ORACLE WEBCENTER SITES DEPLOYED APPLICATION COLLECTIONS

=head2 Configuration Files

Collects Oracle WebCenter Sites deployed application-related configuration
files.

=cut

# Get the deployed application locations
var %app = ()
if ?testFile('fr',catFile($DOMAIN,'config','config.xml'))
{var $obj = xmlLoadFile(last,xmlDisable(xmlParser(),'BCDEPR'))
 loop $xml (xmlFind($obj,'domain/app-deployment|name *="^(cs|cas|Sites)$"'))
 {if ??$xml->find('source-path')->get_data
   var $app{getNativePath(last)} = $xml->find('name')->get_data
 }
}

# Gather the application related files
pretoc '2:Deployed Applications'
loop $dir (keys(%app))
{var $app = $app{$dir}
 debug ' Inside WCS module, analyzing application ',$app
 pretoc "3:'",$app,"' Application"
 debug '  - collecting the configuration files'
 pretoc '4:Configuration Files'
 call sort_files(5,0,\
   grepDir(catDir($dir,'WEB-INF'),'\.xml$','inp'),\
   grepDir(catDir($dir,'WEB-INF','classes'),\
           '(^log4j\.properties|\.xml)$','inp'))
 unpretoc 2
}
unpretoc

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domain.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
toc '%INCLUDE("OFM_WREQ_OFM_WCS_WH_TF.toc")%'
toc '%POP2%'
toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Domain")%'
toc '%INCLUDE("OFM_WREQ_OFM_WCS_DOM_TF.toc")%'
toc '%POP2%'

unpretoc

=head1 SEE ALSO

L<OFM:DCwreq|collect::OFM:DCwreq>,
L<OFM:WLSlib|collect::OFM:WLSlib>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 8.09: Laxmi Prasanna Madu.

=item RDA 8.10: John Grimshire.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut