# DCucm.ctl:354:Collects Oracle WebCenter Universal Content Management Information
# $Id: DCucm.ctl,v 1.13 2015/11/16 08:56:26 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCucm.ctl,v 1.13 2015/11/16 08:56:26 RDA Exp $
#
# Change History
# 20151116  KRA  Extend content server configuration files collection.

=head1 NAME

OFM:DCucm - Collects Oracle WebCenter Universal Content Management Information

=head1 DESCRIPTION

This module collects Oracle WebCenter Universal Content Management-related
information.

The following reports can be generated and are regrouped under C<WebCenter
Universal Content Management>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.UCM module ...',tput('off')

# Initialization
var $AGE  = ${R_LOG_AGE/T:5}
var $TAIL = ${DFT.N_TAIL:1000}

if ?testDir('d',catDir($ORACLE_HOME = ${D_ORACLE_HOME/P:''},'ucm'))
{if $PRIMARY = ${B_PRIMARY}
  var $DOMAIN  = ${D_DOMAIN_HOME:''}
 else
  var $DOMAIN  = ${GRP.ECM.D_DOMAIN_HOME:''}
 var $CS_HOME  = catDir($DOMAIN,'ucm','cs')
 var $IBR_HOME = catDir($DOMAIN,'ucm','ibr')
 var $URM_HOME = catDir($DOMAIN,'ucm','urm')
}
else
{var $CS_HOME   = ${D_CS_HOME:''}
 var $IBR_HOME  = ${D_IBR_HOME:''}
 var $SSPU_HOME = ${D_SSPU_HOME:''}
}

var $MNU = 'WebCenter Content'
var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'

pretoc '^1:',$MNU
pretoc '1+:WebCenter Universal Content Management'

# Load the common macros
run DB:DBinfo()
run OFM:WLSlib()
run RDA:library()

=head2 Content Server

Collects Content Server-related information.

=cut

if $CS_HOME
{debug ' Inside UCM module, getting content server configuration files'
 pretoc '2:Content Server'

 # Collect the configuration files
 pretoc '3:Configuration Files'
 call sort_files(4,$TAIL,\
   catFile($CS_HOME,'bin','intradoc.cfg'),\
   catFile($CS_HOME,'config','config.cfg'),\
   catFile($CS_HOME,'data','components','idccs_components.hda'),\
   catFile($CS_HOME,'data','components','DesktopIntegrationSuite',\
           'config.cfg'),\
   catFile($CS_HOME,'data','conversion','cvtemplates.hda'),\
   catFile($CS_HOME,'data','filestore','config','fsconfig.hda'),\
   grepDir(catDir($CS_HOME,'cmu'),'^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'data','configuration'),'^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'custom','PDFConverter','bin','win32'),\
           '^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'data','providers'),'^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'data','search'),'^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'data','sjobs'),'^\.+$','drv'),\
   grepDir(catDir($CS_HOME,'install'),'_autoinstall\.cfg$','np'),\
   grepDir(catDir($ORACLE_HOME,'ucm','idc'),'^\.+$','drv'))
 unpretoc

 # Collect the analyzer log files
 pretoc '3:Analyzer Log Files'
 call sort_files(4,0,\
   grepDir(catDir($CS_HOME,'bin','logs'),'^\.+$',concat('rvm',$AGE)))
 unpretoc

 # Collect the log files
 pretoc '3:Log Files'
 call sort_files(4,0,\
   grepDir(catDir($CS_HOME,'weblayout','groups','secure','logs'),'^\.+$',\
           concat('rvm',$AGE)))
 unpretoc

 # Collect the trace log files
 pretoc '3:Trace Log Files'
 call sort_files(4,0,\
   grepDir(catDir($CS_HOME,'data','trace'),'\.log$',concat('ipm',$AGE)))
 unpretoc

 # Collect the event log files
 pretoc '3:Event Log Files'
 call sort_files(4,0,\
   grepDir(catDir($CS_HOME,'data','trace','event'),'\.log$',concat('ipm',$AGE)))
 unpretoc

=head3 env_info - Environment Information

For UNIX, collects Dynamic Converter environment information.

=cut

 if isUnix()
 {debug ' Inside UCM module, getting dynamic converter environment information'
  report env_info
  write '---+!! Dynamic Converter Environment Information'
  write $TOC

  # Get the environment variables
  write '---+ Dynamic Converter Environment Variables'
  write '|*Variable*|*Value*|'
  loop $key ('DISPLAY','PATH',@{CUR.W_SHLIB})
   write '|',$key,'|',getEnv($key),' |'
  write $TOP

  # Get the locale information
  if match(getOsName(),'^(aix|hpux|linux|solaris|sunos)$')
  {if loadCommand('locale')
   {prefix
    {write '---+ Locale Information'
     write '|*Name*|*Value*|'
    }
    loop $lin (getLines())
     write '|',key($lin),' |',value($lin),' |'
    if hasOutput(true)
     write $TOP
   }
  }
  toc '3:[[',getFile(),'][rda_report][Environment Information]]'
 }
 unpretoc
}

=head2 Inbound Refinery

Collects Inbound Refinery-related information.

=head3 rep_info - Repository Information

Collects the repository information.

=cut

if $IBR_HOME
{pretoc '2:Inbound Refinery'

 # Collect the repository information
 if ${I_UCM}
 {call setDbTarget(last)
  debug ' Inside UCM module, gathering IBR repository information'
  report rep_info
  if testDb()
  {echo ''
   echo tput('bold'),'The database is not accessible.',tput('off')
   if getDbMessage()
   {echo last
    write '---+ Inbound Refinery Repository Information'
    write 'Database not accessible (',getDbMessage(),')'
    toc '3:[[',getFile(),'][rda_report][Repository Information]]'
   }
   echo ''
  }
  else
  {var $TTL = '---+!! Inbound Refinery Repository Information'
   var $HDR[1] = '|*Format*|*Conversion*|*Description*| *Enabled*|'
   set $sql
   {# SQL1
   "SELECT '|' ||
   "       dformat || ' |' ||
   "       dconversion || ' |' ||
   "       ddescription || ' | ' ||
   "       disenabled || '|'
   " FROM docformats
   " WHERE dconversion <> 'PassThru'
   "/
   }
   call separator(1)
   call writeDb($sql)
   call separator(0,'Repository Information',3)
  }
 }

 # Collect the configuration files
 debug ' Inside UCM module, getting IBR configuration and log files'
 pretoc '3:Configuration Files'
 call sort_files(4,$TAIL,\
   catFile($IBR_HOME,'config','config.cfg'),\
   catFile($IBR_HOME,'bin','intradoc.cfg'),\
   grepDir(catDir($IBR_HOME,'data','configuration'),'^\.+$','drv'),\
   grepDir(catDir($IBR_HOME,'custom','PDFConverter','bin','win32'),\
           '^\.+$','drv'))
 unpretoc

 # Collect the log files
 pretoc '3:Log Files'
 call sort_files(4,0,\
   catFile($IBR_HOME,'bin','IdcRefineryNT.log'),\
   grepDir(catDir($IBR_HOME,'weblayout','groups','secure','logs'),\
           '\.htm$',concat('dirm',$AGE)))
 unpretoc 2

=head2 Digital Asset Management

Collects Digital Asset Management-related information.

=cut

 debug ' Inside UCM module, getting DAM configuration and log files'
 pretoc '2:Digital Asset Management'

 # Collect the configuration files
 pretoc '3:Configuration Files'
 call sort_files(4,$TAIL,\
   grepDir(catDir($IBR_HOME,'data','configuration','dam'),'^\.+$','drv'))
 unpretoc 2
}

=head2 WebCenter Content: Records

Collects Oracle WebCenter Content: Records-related information.

=cut

if $URM_HOME
{debug ' Inside UCM module, getting URM configuration files'
 pretoc '2:WebCenter Content: Records'

 # Collect the configuration files
 pretoc '3:Configuration Files'
 call sort_files(4,$TAIL,\
   catFile($URM_HOME,'bin','intradoc.cfg'),\
   catFile($URM_HOME,'config','config.cfg'),\
   catFile($ORACLE_HOME,'ucm','idc','components','RecordsManagement',\
           'records_management_environment.cfg'),\
   catFile($ORACLE_HOME,'ucm','idc','components','PhysicalContentManager',\
           'physicalcontentmanager_environment.cfg'))
 unpretoc

 # Collect the log files
 pretoc '3:Log Files'
 call sort_files(4,0,\
   grepDir(catDir($URM_HOME,'weblayout','groups','secure','logs'),\
           '\.htm$',concat('irm',$AGE)))
 unpretoc

 # Collect the trace log files
 pretoc '3:Trace Log Files'
 call sort_files(4,0,\
   grepDir(catDir($URM_HOME,'data','trace'),'\.log$',concat('ipm',$AGE)))
 unpretoc

 # Collect the event log files
 pretoc '3:Event Log Files'
 call sort_files(4,0,\
   grepDir(catDir($URM_HOME,'data','trace','event'),'\.log$',\
           concat('ipm',$AGE)))
 unpretoc 2
}

=head2 Web Content Management

=head3 Site Studio Publishing Utility

Collects Site Studio Publishing Utility-related information.

=cut

if $SSPU_HOME
{debug ' Inside UCM module, getting SSPU configuration and log files'
 pretoc '2:Web Content Management'
 pretoc '3:Site Studio Publishing Utility'

 # Collect the configuration files
 pretoc '4:Configuration Files'
 call sort_files(5,$TAIL,\
   catFile($SSPU_HOME,'sitestudio.config'),\
   grepDir($SSPU_HOME,'^cns\.(db2|oracle|sqlserver)\.config$','ip'))
 unpretoc

 # Collect the log files
 pretoc '4:Log Files'
 call sort_files(5,$TAIL,catFile($SSPU_HOME,'syndicator.log'))
 unpretoc 3
}

=head1 ORACLE HOME INFORMATION

=head2 Manifest Information

Gathers the Oracle home manifest information.

=cut

if and($PRIMARY,length($ORACLE_HOME))
{debug ' Inside UCM module, getting Oracle home manifest information \
         (can take time)'
 pretoc '2:Manifest Information'
 call dsp_manifest(3,$ORACLE_HOME)
 unpretoc

=head2 dc_templates - DC Templates

Gathers the dynamic converter template files.

=cut

 debug ' Inside UCM module, getting dynamic converter templates'
 report dc_templates
 prefix
 {write '---+ Dynamic Converter Templates Files'
  write '   * Links point to files that have been collected in their \
              original format. Opening them directly in your browser \
              can present risks. To prevent them, access the file \
              outside the browser or use the link to save them and use \
              an adequate viewer.'
  write '|*File Name*| *Size*|*Last Modified Date*|'
 }
 loop $fil (grepDir(catDir($ORACLE_HOME,'ucm','Distribution',\
                           'DynamicConverterTemplates'),\
                    '^\.+$','drv'))
 {if ?testFile('fr',$fil)
  {var $lnk = encode(addSymbol($fil))
   var $siz = getSize($fil)
   if $siz
   {output d,concat('dct_',basename($fil))
    if ${CUR.O_LAST}->write_data($fil)
     var $lnk = concat('[[',${CUR.O_LAST}->get_raw(true),'][_blank][',$lnk,']]')
    end ${CUR.O_LAST}
   }
   write '|',$lnk,' | ',$siz,'|',getLastModify($fil,'<UTC>'),' |'
  }
 }
 if isCreated(true)
 {write $TOP
  toc '2:[[',getFile(),'][rda_report][DC Templates]]'
 }
}

=head1 COMMON HOME INFORMATION

Includes the reports generated by the L<abr:IREQ|collect::OFM:DCireq> module
about the common home.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Common Product Home")%'
toc '%INCLUDE("OFM_IREQ_OFM_UCM_CH_TF.toc")%'
toc '%POP2%'

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domain.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
toc '%INCLUDE("OFM_WREQ_OFM_UCM_WH_TF.toc")%'
toc '%POP2%'
toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Domain")%'
toc '%INCLUDE("OFM_WREQ_OFM_UCM_DOM_TF.toc")%'
toc '%POP2%'

# Disable the group title in next index
toc '-:',$MNU

=head1 SEE ALSO

L<DB:DBinfo|collect::DB:DBinfo>,
L<OFM:DCecm|collect::OFM:DCecm>,
L<OFM:DCireq|collect::OFM:DCireq>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<OFM:WLSlib|collect::OFM:WLSlib>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.17: Jeremy Reilmann, Matt Rudd.

=item RDA 4.21: Jeremy Reilmann.

=item RDA 4.24: Greg Cook, Andrew Salt.

=item RDA 4.28: Alan Boucher.

=item RDA 4.29: Alan Boucher, Thrond Toftley.

=item RDA 8.02: Alan Boucher.

=item RDA 8.03: Alan Boucher, Cindi Canfield.

=item RDA 8.06: Raju Bhandare.

=item RDA 8.07: Alan Boucher.

=item RDA 8.10: Alan Boucher.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut