# DCosb.ctl:378:Collects Oracle Service Bus Information
# $Id: DCosb.ctl,v 1.11 2015/07/03 12:04:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCosb.ctl,v 1.11 2015/07/03 12:04:44 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

OFM:DCosb - Collects Oracle Service Bus Information

=head1 DESCRIPTION

This module collects Oracle Service Bus-related information. The
following reports can be generated and are regrouped under C<Oracle Service
Bus>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.OSB module ...',tput('off')

# Initialization
var $DETAIL   = ${W_DETAIL:'MAX'}
var $OSB_HOME = ${D_HOME:''}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle Service Bus',check($DETAIL,'^BAS$',' (Basic)',\
                                            '^MIN$',' (Minimum)')

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Oracle Service Bus home
collection.

=cut

debug ' Inside OSB module, collecting defined abbreviations'
report abbr
prefix
{write '---+ OSB Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 product_info - Product Information

Gathers the product information when it is available (applicable for C<Minimum>
and C<Maximum> collections).

=cut

if match($DETAIL,'^(MAX|MIN)$')
{# Load the common macros
 run OFM:WLSlib()
 run RDA:INVinfo()

 if ?testDir('d',catDir($OSB_HOME,'inventory'))
 {debug ' Inside OSB module, processing Product Information (can take time)'
  report product_info
  prefix
  {write '---+!! Oracle Service Bus Home Product Information'
   write '---## From ',encode($OSB_HOME),' '
   write $TOC
  }
  call inventory_details(lastDir(),true)
  if isCreated(true)
   toc '2:[[',getFile(),'][rda_report][Product Information]]'

=head2 Manifest Information

Gathers the Oracle home manifest information (applicable for C<Maximum>
collection).

=cut

  if compare('eq',$DETAIL,'MAX')
  {debug ' Inside OSB module, getting Oracle home manifest information \
           (can take time)'
   pretoc '2:Manifest Information'
   call dsp_manifest(3,$OSB_HOME)
   unpretoc
  }
 }

=head2 patch_list - Patch Applied Using Smart Update

Lists the Oracle Service Bus patches applied using Smart Update, when
available (applicable for C<Minimum> and C<Maximum> collections).

=cut

 if and(${B_RUN_BSU},\
        testDir('dr',catDir($OSB_HOME,upDir(),'utils','bsu')))
 {debug ' Inside OSB module, gathering patches applied using Smart Update'
  report patch_list
  prefix
   write '---+ Patches Applied Using Smart Update'
  var $dir = lastDir()
  var $opt = concat(' -view -status=applied -prod_dir=',\
                    getNativePath($OSB_HOME))
  if or(isCygwin(),isWindows())
  {write '---## Using: ',concat(catFile($dir,'bsu.cmd'),$opt)
   var $job = createTemp('PCH','.bat',true)
   call writeTemp('PCH','@echo off')
   call writeTemp('PCH','cd /d "',getNativePath($dir),'"')
   call writeTemp('PCH','bsu.cmd',$opt)
   call closeTemp('PCH')
   call writeCommand($job)
   call unlinkTemp('PCH')
  }
  elsif isUnix()
  {write '---## Using: ',concat(catFile($dir,'bsu.sh'),$opt)
   var $job = createTemp('PCH','.sh',true)
   call writeTemp('PCH','cd "',$dir,'"')
   call writeTemp('PCH','bsu.sh',$opt)
   call closeTemp('PCH')
   call writeCommand($job)
   call unlinkTemp('PCH')
  }
  if isCreated(true)
   toc '2:[[',getFile(),'][rda_report][Patches Applied Using Smart Update]]'
 }

=head1 COMMON HOME INFORMATION

Includes the reports generated by the L<abr:IREQ|collect::OFM:DCireq> module
about the common home when present (applicable for C<Minimum> and C<Maximum>
collections).

=cut

 toc '%PUSH("%SPLIT%")%'
 toc '%PUSH("1+:Common Product Home")%'
 toc '%INCLUDE("OFM_IREQ_OFM_OSB_CH_TF.toc")%'
 toc '%POP2%'
}

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domains.

=cut

# Analyze the domain requests
var %tbl = ()
loop $req (@req = ${CUR.O_SETUP}->search('^WREQ_OFM_OSB_DOM'))
{var $dom = $req->get_first('I_DOMAIN')
 if ?$dom->get_first('I_WL_HOME')
  var $tbl{last->get_oid,$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
 else
  var $tbl{'WH',$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
}

# Include the table of content files produced by WREQ
loop $oid (keys(%tbl))
{if $orp = compare('eq',$oid,'WH')
  toc '%PUSH("0:   * Orphan Domains")%'
 toc '%PUSH("%SPLIT%")%'
 toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
 toc '%INCLUDE("OFM_WREQ_OFM_OSB_',$oid,'_TF.toc")%'
 toc '%POP2%'
 loop $tid (keys($tbl = $tbl{$oid}))
 {toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1+:',"'",$tbl->{$tid},"'",' Domain")%'
  toc '%INCLUDE("OFM_',$tid,'_TF.toc")%'
  toc '%POP2%'
 }
 if $orp
  toc '%POP%'
}

=head2 HCVE

Performs the postinstallation checks (applicable for C<Minimum> and C<Maximum>
collections).

=cut

if match($DETAIL,'^(MAX|MIN)$')
{debug ' Inside OSB module, executing the postinstallation checks'
 var $tbl = {}
 loop $req (@req)
 {var $tgt = addTarget($req->get_first('I_DOMAIN'))
  var $tbl->{catDir($tgt->get_domain('.'))} = \
    [catDir($tgt->get_domain('top')),$tgt->get_domain('nam','')]
 }
 var ${RUN.HCVE.OFM.OSB.T_DOMAINS} = $tbl
 test TOOL:TLhcve('OFM:Posb111_gen')
}

unpretoc

=head1 SEE ALSO

L<OFM:DCireq|collect::OFM:DCireq>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<OFM:WLSlib|collect::OFM:WLSlib>,
L<RDA:INVinfo|collect::RDA:INVinfo>

=begin credits

=over 10

=item RDA 4.22:  Maria Salzberger.

=item RDA 4.24:  Greg Cook, Andrew Salt, Maria Salzberger.

=item RDA 8.00:  Shawn Bailey, Maria Salzberger.

=item RDA 8.04:  Wes Root.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut