# DCiws.ctl:317:Collects Oracle iPlanet Web Server Information
# $Id: DCiws.ctl,v 1.5 2015/07/22 15:31:59 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCiws.ctl,v 1.5 2015/07/22 15:31:59 RDA Exp $
#
# Change History
# 20150722  KRA  Extend the collections.

=head1 NAME

OFM:DCiws - Collects Oracle iPlanet Web Server Information

=head1 DESCRIPTION

This module collects information related to Oracle iPlanet Web Server,
formerly known as Sun Java System Web Server. The module covers Oracle iPlanet
Web Server Release 6.x and later.

The following reports can be generated and are regrouped under
C<iPlanet Web Server>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing OFM.IWS module ...',tput('off')

# Initialization
var $INS_ROOT = ${D_INSTANCE_ROOT:''}
var $IWS_HOME = ${D_HOME:''}
var $TAIL     = ${DFT.N_TAIL:1000}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:iPlanet Web Server'

# Load the common macros
run RDA:library()

=head1 IPLANET WEB SERVER INFORMATION

=head2 version_info - Version Information

Gathers Oracle iPlanet Web Server version information.

=cut

debug ' Inside IWS module, gathering version information'
pretoc '2:Server Information'
if ?testFile('f',catFile($IWS_HOME,'bin',${AS.EXE:'wadm'}))
 var $cmd = concat(lastCommand(),' --version')
elsif ?testFile('f',catFile($IWS_HOME,'bin','https','bin',${AS.EXE:'webservd'}))
 var $cmd = concat(lastCommand(),' -v')
else
 var $cmd = undef
if ?$cmd
{report version_info
 prefix
 {write '---+ Oracle iPlanet Web Server Version Information'
  write '---## Using: ',encode($cmd)
 }
 call writeCommand(concat($cmd,' 2>&1'))
 if isCreated(true)
  toc '3:[[',getFile(),'][rda_report][Version Information]]'
}

=head2 plugin_ver - Plugin Library Version

Collects the plugin library version information on Windows.

=cut

if ?testDir('d',$IWS_HOME)
{if or(isWindows(),isCygwin())
 {debug 'Inside IWS module, gathering plugin library version'
  report plugin_ver
  title '---+!! Plugin Library Version Information'
  title '%TOC3-2%'
  loop $dir (findDir($IWS_HOME,'^WebServer\d+\.\d+$','p'))
  {if ?$fil = testFile('f',catFile($dir,'plugins','lib','proxy61.dll'))
   {write '---+ File ',basename($fil)
    call statFile('p',$fil)
    write '%BR%'
    var $inf = getVersionInfo($fil)
    loop $key (keys($inf))
     write '|*',replace($key,'\012','',true),' *|',\
                replace($inf->{$key},'\012','',true),' |'
    write $TOP
   }
  }
  if isCreated(true)
   toc '3:[[',getFile(),'][rda_report][Plugin Library Version]]'
 }

=head2 Configuration Files

Gathers Administration Server-related configuration files.

=cut

 debug ' Inside IWS module, collecting the admin configuration files'
 pretoc '3:Configuration Files'
 var (@dir,@fil) = (findDir($IWS_HOME,'^https\-Weblogic\d+\.\d+$','p'))
 loop $dir (@dir)
  call push(@fil,catFile($dir,'config','magnus.conf'),\
                 catFile($dir,'config','obj.conf'))
 call sort_files(4,0,\
   grepDir(catDir($IWS_HOME,'admin-server','config'),'^\.+$','pv'),\
   grepDir(catDir($IWS_HOME,'https-admserv','config'),'^\.+$','pv'),\
   grepDir(catDir($IWS_HOME,'httpacl'),'^\.+$','pv'),\
   @fil)
 unpretoc

=head2 Log Files

Gathers Administration Server-related log files.

=cut

 debug ' Inside IWS module, collecting the admin log files'
 pretoc '3:Log Files'
 var @fil = ()
 loop $dir (@dir)
  call push(@fil,grepDir(catDir($dir,'logs'),'^\.+$','pv'))
 call sort_files(4,$TAIL,\
   grepDir(catDir($IWS_HOME,'admin-server','logs'),'^\.+$','pv'),\
   grepDir(catDir($IWS_HOME,'https-admserv','logs'),'^\.+$','pv'),\
   @fil)
 unpretoc
}
unpretoc

=head1 WEB SERVER INSTANCE INFORMATION

=head2 Configuration Files

Gathers Web Server instance-related configuration files.

=cut

loop $ins (@{T_INSTANCES})
{debug ' Inside IWS module, analyzing instance ',$ins
 var $top = catDir($INS_ROOT,$ins)
 pretoc "2:'",$ins,"' Instance"

 debug '  - collecting the configuration files'
 pretoc '3:Configuration Files'
 call sort_files(4,0,grepDir(catDir($top,'config'),'^\.+$','pv'))
 unpretoc

=head2 Log Files

Gathers Web Server instance-related log files.

=cut

 debug '  - collecting the log files'
 pretoc '3:Log Files'
 call sort_files(4,$TAIL,grepDir(catDir($top,'logs'),'^\.+$','pv'))
 unpretoc 2
}

unpretoc

=head1 SEE ALSO

L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.26: Jeff Brown.

=item RDA 8.03: Ramakrishnan Madaparambath.

=item RDA 8.09: Laurent Goldsztejn.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut