# DCcohr.ctl:365:Collects Oracle Coherence Information
# $Id: DCcohr.ctl,v 1.6 2015/07/03 12:04:44 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/OFM/DCcohr.ctl,v 1.6 2015/07/03 12:04:44 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

OFM:DCcohr - Collects Oracle Coherence Information

=head1 DESCRIPTION

This module collects Oracle Coherence-related information.

The following reports can be generated and are regrouped under C<Oracle
Coherence>:

=cut

echo tput('bold'),'Processing OFM.COHR module ...',tput('off')

# Initialization
var $COHR_HOME = ${D_HOME:''}
var $TAIL      = ${DFT.N_TAIL:1000}

if and(${B_CUSTOM_SCRIPTS},not(${B_CUSTOM_SCRIPTS_BIN}))
 var $CUSTOM_SCRIPTS_DIR = ${D_CUSTOM_SCRIPTS:''}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Oracle Coherence'

# Load the common macros
run RDA:library()

=head2 Start Scripts

Gathers the Oracle Coherence Server-related start scripts.

=cut

debug ' Inside COHR module, collecting the start scripts'
pretoc '2:Start Scripts'
call sort_files(3,0,grepDir(catDir($COHR_HOME,'bin'),'\.(cmd|sh)$','p'))

# Collect the custom scripts if used
if length($CUSTOM_SCRIPTS_DIR)
{pretoc '3:Custom Start Scripts'
 call sort_files(4,0,grepDir($CUSTOM_SCRIPTS_DIR,'\.(cmd|sh)$','dr',1))
 unpretoc
}
unpretoc

=head2 Configuration Files

Gathers Oracle Coherence-related configuration files.

=cut

debug ' Inside COHR module, collecting the configuration files'
pretoc '2:Configuration Files'
if ?$pgm = findCommand('unzip')
{var $src = catCommand($COHR_HOME,'lib','coherence.jar')
 loop $nam ('coherence-cache-config.xml',\
            'coherence-pof-config.xml',\
            'tangosol-coherence.xml',\
            'tangosol-coherence-override-dev.xml',\
            'tangosol-coherence-override-eval.xml',\
            'tangosol-coherence-override-prod.xml')
 {var $cmd = concat($pgm,' -p ',$src,' ',$nam)
  report $nam
  prefix
  {write '---+ Display of ',encode($nam),' File'
   write '---## Using: ',encode($cmd)
  }
  call writeCommand($cmd)
  if isCreated(true)
  {write $TOP
   toc '3:[[',getFile(),'][rda_report][',encode($nam),']]'
  }
 }
}
loop $src (grepDir(catDir($COHR_HOME,'bin'),cond(isWindows(),'\.cmd$',\
                                                 isCygwin(), '\.cmd$',\
                                                             '\.sh$'),'ip'))
{loop $str (grepFile($src,'COHERENCE_OPTS="?-D.*=.*"?$'))
 {var ($typ,$fil) = match($str,'COHERENCE_OPTS="?-D(.*?)=(.*?)"?$')
  call addDataValue($typ,$fil)
 }
}
loop $typ (getDataKeys())
{pretoc '3:',$typ
 call sort_files(4,$TAIL,getDataValue($typ))
 unpretoc
}
unpretoc

=head1 COMMON HOME INFORMATION

Includes the reports generated by the L<abr:IREQ|collect::OFM:DCireq> module
about the common home.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Common Product Home")%'
toc '%INCLUDE("OFM_IREQ_OFM_COHR_CH_TF.toc")%'
toc '%POP2%'

=head1 ORACLE WEBLOGIC SERVER DOMAIN COLLECTIONS

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domain.

=cut

toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
toc '%INCLUDE("OFM_WREQ_OFM_COHR_WH_TF.toc")%'
toc '%POP2%'
toc '%PUSH("%SPLIT%")%'
toc '%PUSH("1+:Oracle WebLogic Server Domain")%'
toc '%INCLUDE("OFM_WREQ_OFM_COHR_DOM_TF.toc")%'
toc '%POP2%'

unpretoc

=head1 SEE ALSO

L<OFM:DCireq|collect::OFM:DCireq>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 4.17: Miguel Hernandez.

=item RDA 8.02: Srihari Gaddam.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut