# DCofap.ctl:601:Collects Oracle Fusion Applications Provisioning Information
# $Id: DCofap.ctl,v 1.4 2015/07/03 11:32:28 RDA Exp $
# ARCS: $Header: /home/cvs/cvs/RDA_8/src/scripting/lib/collect/APPS/DCofap.ctl,v 1.4 2015/07/03 11:32:28 RDA Exp $
#
# Change History
# 20150703  MSC  Improve the documentation.

=head1 NAME

APPS:DCofap - Collects Oracle Fusion Applications Provisioning Information

=head1 DESCRIPTION

This module collects Oracle Fusion Applications Provisioning-related
information. The following reports can be generated and are regrouped under
C<Fusion Applications Provisioning>:

=head1 REPORTS

=cut

echo tput('bold'),'Processing APPS.OFAP module ...',tput('off')

# Initialization
var $ROOT = ${D_ROOT:''}

var $TOC = '%TOC%'
var $TOP = '[[#Top][Back to top]]'
pretoc '1:Fusion Applications Provisioning'

# Set the symbols
call setSymbol('$TOP',$ROOT)

# Load the common macros
run DB:DBinfo()
run RDA:library()

=head2 abbr - Abbreviations

Displays the RDA abbreviations defined for the Oracle Fusion Applications
Provisioning home collection.

=cut

debug ' Inside OFAP module, collecting defined abbreviations'
report abbr
prefix
{write '---+ Oracle Fusion Applications Provisioning Home Abbreviations'
 write '|*Abbreviation*|*Location*|'
}
var %hsh = getSymbols()
loop $key (keys(%hsh))
 write '|',$key,' |',$hsh{$key},' |'
if isCreated(true)
 toc '2:[[',getFile(),'][rda_report][Abbreviations]]'

=head2 rep_info - Repository Information

Collects the repository information.

=cut

if ${I_APPS}
{call setDbTarget(last)

 debug ' Inside OFAP module, gathering the repository information'
 report rep_info
 if testDb()
 {echo ''
  echo tput('bold'),'The database is not accessible.',tput('off')
  if getDbMessage()
  {echo last
   write '---+ OFAP Repository Information'
   write 'Database not accessible (',getDbMessage(),')'
   toc '2:[[',getFile(),'][rda_report][Repository Information]]'
  }
  echo ''
 }
 else
 {var $TTL = '---+!! OFAP Repository Information'
  var @TTL = ('',\
              '---+ Release Information',\
              '---+ Deployed Domains Information')
  var @HDR = ('',\
              '|*ARU Release Name*|*Release Name*|')
  set $sql
  {# SQL1
  "SELECT '|' ||
  "       aru_release_name || ' |' ||
  "       release_name || ' |'
  " FROM ad_product_groups
  "/
  }
  var ($HDR[2],$col2) = getDbColumns('RDA','ASK_DEPLOYED_DOMAINS')
  call clearDbColumns('RDA')
  if $col2
  {append $sql
   {# MACRO separator(2)
   "# SQL2
   "SELECT :1
   " FROM ask_deployed_domains
   "/
   }
  }
  call separator(1)
  call writeDb(bindDb($sql,$col2))
  call separator(0,'Repository Information')
 }
}

=head2 comps_xml - comps.xml File

Collects the F<comps.xml file> from the inventory directory.

=cut

if ?$fil = testFile('fr',catFile($ROOT,'fusionapps','applications',\
                                 'inventory','ContentsXML','comps.xml'))
{debug ' Inside OFAP module, gathering the comps.xml file'
 report comps_xml
 prefix
 {write '---+ comps.xml File'
  write '---## Information Taken from ',encode($fil)
 }
 call writeFile($fil)
 if isCreated(true)
 {write $TOP
  toc '2:[[',getFile(),'][rda_report][comps.xml File]]'
 }
}

=head2 Configuration Files

Gathers the configuration files.

=cut

debug ' Inside OFAP module, collecting the configuration files'
pretoc '2:Configuration Files'
call sort_files(3,0,\
  grepDir(catDir($ROOT,'instance','fapatch'),'^\.+$','drv'),\
  cleanPath([$ROOT,upDir(),'faprov','provisioning','bin',\
             'provisioning.rsp'],true))
unpretoc

=head2 Oracle Instance Information

Includes the reports generated by the L<abr:IREQ|collect::OFM:DCireq> module
about the Oracle instances and their associated Oracle homes.

=cut

# Analyze the instance requests
var %tbl = ()
loop $req (${CUR.O_SETUP}->search('^IREQ_APPS_OFAP_OI'))
{var $ins = $req->get_first('I_ORACLE_INSTANCE')
 if ?$ins->get_first('I_ORACLE_HOME')->get_prime('I_COMMON_HOME')
  var $tbl{last->get_oid,$req->get_oid} = $ins->get_first('D_ORACLE_INSTANCE')
 else
  var $tbl{'CH',$req->get_oid} = $ins->get_first('D_ORACLE_INSTANCE')
}

# Include the table of content files produced by IREQ
loop $oid (keys(%tbl))
{toc '%PUSH("1+:Common Product Home")%'
 toc '%INCLUDE("OFM_IREQ_APPS_OFAP_',$oid,'_TF.toc")%'
 toc '%POP%'
 loop $tid (keys($tbl = $tbl{$oid}))
 {toc '%PUSH("0:      * ',"'",basename($tbl->{$tid}),"'",' Instance")%'
  toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1++:Associated Oracle Home")%'
  toc '%INCLUDE("OFM_',replace($tid,'_OI','_OH'),'_TF.toc",1)%'
  toc '%POP2%'
  toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1++:Instance Home")%'
  toc '%INCLUDE("OFM_',$tid,'_TF.toc")%'
  toc '%POP3%'
 }
}

=head2 Oracle WebLogic Server Domain Information

It includes all reports produced by the L<abr:WREQ|collect::OFM:DCwreq> module
for the specified Oracle WebLogic Server domains.

=cut

# Analyze the domain requests
var %tbl = ()
loop $req (${CUR.O_SETUP}->search('^WREQ_APPS_OFAP_DOM'))
{var $dom = $req->get_first('I_DOMAIN')
 if ?$dom->get_first('I_WL_HOME')
  var $tbl{last->get_oid,$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
 else
  var $tbl{'WH',$req->get_oid} = $dom->get_first('T_DOMAIN_NAME')
}

# Include the table of content files produced by WREQ
loop $oid (keys(%tbl))
{if $orp = compare('eq',$oid,'WH')
  toc '%PUSH("0:   * Orphan Domains")%'
 toc '%PUSH("%SPLIT%")%'
 toc '%PUSH("1+:Oracle WebLogic Server Overview")%'
 toc '%INCLUDE("OFM_WREQ_APPS_OFAP_',$oid,'_TF.toc")%'
 toc '%POP2%'
 loop $tid (keys($tbl = $tbl{$oid}))
 {toc '%PUSH("%SPLIT%")%'
  toc '%PUSH("1+:',"'",$tbl->{$tid},"'",' Domain")%'
  toc '%INCLUDE("OFM_',$tid,'_TF.toc")%'
  toc '%POP2%'
 }
 if $orp
  toc '%POP%'
}

unpretoc

=head1 SEE ALSO

L<DB:DBinfo|collect::DB:DBinfo>,
L<OFM:DCireq|collect::OFM:DCireq>,
L<OFM:DCwreq|collect::OFM:DCwreq>,
L<RDA:library|collect::RDA:library>

=begin credits

=over 10

=item RDA 8.04: Sunder Subramanyan.

=item RDA 8.07: Lynne Cann, Sunder Subramanyan.

=back

=end credits

=head1 COPYRIGHT NOTICE

Copyright (c) 2002, 2016, Oracle and/or its affiliates. All rights reserved.

=head1 TRADEMARK NOTICE

Oracle and Java are registered trademarks of Oracle and/or its
affiliates. Other names may be trademarks of their respective owners.

=cut